Create Reminders Routine - Shows Same Invoice Twice

SarahSoltec

When I am running the create reminders routine on NAV 2009 SP1 with the 'Only Entries with Overdue Amounts' unticked it correctly brings through my invoices outstanding but not due, which is what I want, but it is showing the same invoice twice. All Invoices which are actually due only show once.

The Invoice is due on the 30/09/2011 and I am running the Reminder Letters Routine with a Document Date of 01/08/2011 and the Use Header Level Selected.

Has anyone come across this issue before and how can I prevent this Invoices appearing twice?

Calico

This is a bug in codeunit 392.

    IF (NOT OverdueEntriesOnly) THEN BEGIN
      IF CustLedgEntry.FIND('-') THEN BEGIN
        REPEAT
          IF CustLedgEntry."Due Date" >= ReminderHeaderReq."Document Date" THEN BEGIN
            IF NOT AmountsNotDueLineInserted THEN BEGIN
              ReminderLine.INIT;
              NextLineNo := GetHighestLineNo(ReminderHeader."No.") + 10000;
              ReminderLine."Reminder No." := ReminderHeader."No.";
              ReminderLine."Line No." := NextLineNo;
              ReminderLine."Line Type" := ReminderLine."Line Type"::"Not Due";
              ReminderLine.INSERT;
              NextLineNo := NextLineNo + 10000;
              ReminderLine.INIT;
              ReminderLine."Reminder No." := ReminderHeader."No.";
              ReminderLine."Line No." := NextLineNo;
              ReminderLine.Description := Text0000;
              ReminderLine.Type := ReminderLine.Type::"Customer Ledger Entry";
              ReminderLine.VALIDATE("Entry No.",CustLedgEntry."Entry No.");
              ReminderLine."No. of Reminders" := 0;
              ReminderLine."Line Type" := ReminderLine."Line Type"::"Not Due";
              ReminderLine.INSERT;
              AmountsNotDueLineInserted := TRUE;
            END;
            NextLineNo := NextLineNo + 10000;
            ReminderLine.INIT;
            ReminderLine."Reminder No." := ReminderHeader."No.";
            ReminderLine."Line No." := NextLineNo;
            ReminderLine.Type := ReminderLine.Type::"Customer Ledger Entry";
            ReminderLine.VALIDATE("Entry No.",CustLedgEntry."Entry No.");
            ReminderLine."No. of Reminders" := 0;
            ReminderLine."Line Type" := ReminderLine."Line Type"::"Not Due";
            ReminderLine.INSERT;
          END;
        UNTIL CustLedgEntry.NEXT = 0;

The first occurence of

ReminderLine.Type := ReminderLine.Type::"Customer Ledger Entry";
ReminderLine.VALIDATE("Entry No.",CustLedgEntry."Entry No.");

should be commented out which will result in a blank line and then a line with the description "Open Entries not yet due" (Text0000 - you don't see it currently because VALIDATE (ing) the "Entry No." overwrites the description) above the not due lines.