Relation to table

vishal.vgarg

Hello Everyone

I need to have all the relations(to find out how the different tables are relate or what is the relation) for a particular table. This is in continuation to my previous query .Can anyone let me know how to get the exact relations.I tried with dictRelation = df.relationObject(); but this gives only the table name and no the relation nventTable.altconfigId == ConfigTable.configId).

Thanks in advance

Kossykh_Artyom

static void Job14(Args _args)
{
    DictTable       dictTable;
    DictRelation    dictRelation;

    str             relationName;
    int             relationCnt;
    int             cnt;
    int             linesCnt;
    int             cnt2;
    str             externFieldName;
    str             fieldName;
    ;
    dictTable = new DictTable(tableNum(inventTable));
    dictRelation = new DictRelation(tableNum(InventTable));
    
    relationCnt = dictTable.relationCnt();

    for(cnt = 1; cnt <= relationCnt; cnt++)
    {
        relationName = dictTable.relation(cnt);
        info(relationName);
        dictRelation.loadNameRelation(relationName);

        linesCnt = dictRelation.lines();
        for(cnt2 = 1; cnt2 <= linesCnt; cnt2++)
        {
            externFieldName = fieldId2Name(dictRelation.externTable(),dictRelation.lineExternTableValue(cnt2));
            fieldName       = fieldId2Name(dictRelation.table(),dictRelation.lineTableValue(cnt2));
            info(strfmt("%1.%2 = %3.%4",tableId2Name(dictRelation.table()),fieldName,tableId2Name(dictRelation.externTable()),externFieldName));
        }
        

    }
}