lowercase to UPPERCASE in CODE Fields

OBJECT Report 50100 sql fix
{
  OBJECT-PROPERTIES
  {
    Date=11/12/06;
    Time=12:34:18 PM;
    Modified=Yes;
    Version List=;
  }
  PROPERTIES
  {
    ProcessingOnly=Yes;
    OnInitReport=BEGIN
                   FileName := 'C:\sqlfix.sql';
                   CompName := COMPANYNAME;
                 END;

    OnPreReport=BEGIN
                  MyFile.CREATE(FileName);
                  MyFile.WRITEMODE(TRUE);
                  MyFile.TEXTMODE(TRUE);
                END;

    OnPostReport=BEGIN
                   MyFile.CLOSE;
                 END;

  }
  DATAITEMS
  {
    { PROPERTIES
      {
        DataItemTable=Table2000000001;
        DataItemTableView=SORTING(Type,Company Name,ID)
                          WHERE(Type=CONST(Table));
        OnPreDataItem=BEGIN
                        FILTERGROUP(10);
                        SETFILTER(ID,'<>385&<>1550020');    //add any table that is company independent here
                        FILTERGROUP(11);
                        SETRANGE(ID,0,99008535);  // filter out million range tables.cause they are company independent
                      END;

        OnAfterGetRecord=BEGIN
                           tabref.OPEN(ID);
                           IF tabref.FINDFIRST THEN BEGIN
                             fields.SETRANGE(TableNo,ID);
                             fields.SETRANGE(Type,fields.Type::Code);
                             fields.SETRANGE(Class,fields.Class::Normal);
                             I := 0;
                             IF fields.FIND('-') THEN BEGIN
                               MyFile.WRITE('update [' + CompName + '$' + FixName(Name) + ']');
                               MyFile.WRITE('SET');
                               REPEAT
                                 IF I MOD 10 = 0 THEN BEGIN
                                   setstring := '[' + FixName(fields.FieldName) + '] = upper([' + FixName(fields.FieldName) + '])';
                                 END ELSE BEGIN
                                 setstring := setstring + ', ' +
                                                '[' + FixName(fields.FieldName) + '] = upper([' + FixName(fields.FieldName) + '])';
                                 END;
                                 I += 1;
                                 IF I MOD 10 = 0 THEN BEGIN
                                   IF I = fields.COUNT THEN
                                     MyFile.WRITE(setstring)
                                   ELSE
                                     MyFile.WRITE(setstring + ',');
                                   setstring := '';
                                 END;
                               UNTIL fields.NEXT = 0;
                               MyFile.WRITE(setstring);
                               MyFile.WRITE('');
                             END;
                           END;
                         END;

        ReqFilterFields=ID,Name;
      }
      SECTIONS
      {
        { PROPERTIES
          {
            SectionType=Body;
            SectionWidth=12000;
            SectionHeight=846;
          }
          CONTROLS
          {
          }
           }
      }
       }
  }
  REQUESTFORM
  {
    PROPERTIES
    {
      Width=9020;
      Height=3410;
    }
    CONTROLS
    {
      { 1000000000;TextBox;2970 ;440  ;5060 ;440  ;SourceExpr=FileName }
      { 1000000001;Label  ;0    ;440  ;2530 ;440  ;CaptionML=ENU=File Name }
      { 1000000002;TextBox;2970 ;990  ;5060 ;440  ;SourceExpr=CompName }
      { 1000000003;Label  ;0    ;990  ;2530 ;440  ;CaptionML=ENU=Company Name }
    }
  }
  CODE
  {
    VAR
      fields@1000000000 : Record 2000000041;
      tabref@1000000001 : RecordRef;
      FileName@1000000002 : Text[250];
      MyFile@1000000003 : File;
      CompName@1000000004 : Text[250];
      setstring@1000000005 : Text[1024];
      I@1000000006 : Integer;
      quote@1000000007 : TextConst 'ENU=''';

    PROCEDURE FixName@1000000041(fieldname@1000000000 : Text[100]) : Text[100];
    BEGIN
      fieldname := CONVERTSTR(fieldname,'.','_');
      fieldname := CONVERTSTR(fieldname,'/','_');
      fieldname := CONVERTSTR(fieldname,'\','_');
      fieldname := CONVERTSTR(fieldname,quote,'_');
      EXIT(fieldname);
    END;

    BEGIN
    {
      //directions import the report. run it. it will create sqlfix.sql file. Open enterprise manager and paste the file and run it on the
        navision database
    }
    END.
  }
}